//
// Test Rig for Primo EM182 capsules
//
// Copyright 2015, Fernando Lopez-Lezcano, All Rights Reserved
// nando@ccrma.stanford.edu
//
//
//  This program is free software: you can redistribute it and/or modify
//  it under the terms of the GNU General Public License as published by
//  the Free Software Foundation, either version 3 of the License, or
//  (at your option) any later version.
//
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//  GNU General Public License for more details.
//
//  You should have received a copy of the GNU General Public License
//  along with this program.  If not, see <http://www.gnu.org/licenses/>.
//
//
// 3d Models released under the Creative Commons license as follows:
//   Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0)
// http://creativecommons.org/licenses/by-nc-sa/4.0/

// dimensions of the EM182 electret microphone
capsule_radius = 5;
capsule_radius_i = 2.5;
capsule_height = 4.5;

// wall thickness of capsule holder
wall = 1;

// contact pads
pad_offset = 3.56;

// slot for contact
contact_width = 0.85;

// length of contact
contact_length = 2.9;

// depth of contact channel (includes contact)
contact_depth = 0.79;

// island around contact
contact_border = 0.5;

// contact offset from center line
contact_offset = 0.3;

// support depth
disk_depth = 1.17;
disk_edge = 0.49;

// adjustment for the inner radius of the capsule holder
//   measured inside diameter of a trial print was around 7.5 to 8.2 
//   instead of 10, capsule diameter was 9.99)
fudge = 0.15;

// number of facets for rendering cylinders
facets = 64;


// one slot for a contact
module contact (trans, angle, slot = false) {
    rotate([0, 0, angle]) {
        translate(trans) {
            translate([- (contact_width + 2 * contact_border) / 2, 0, 0]) {
                if (slot == false) {
                    difference() {
                        // base for the contact
                        cube([contact_width + 2 * contact_border, capsule_radius + wall / 2, disk_depth]);
                        translate([contact_width / 2, 0, contact_depth]) {
                            // channel for clip
                            cube([contact_width, capsule_radius + wall / 2, disk_depth]);
                        }
                        // cutout for clip from edge of disk
                        translate([contact_width / 2, capsule_radius - 0.666, 0]) {
                            cube([contact_width, contact_length, disk_depth]);
                        }
                    }
                } else {
                    // just the cutouts
                        translate([contact_width / 2, 0, contact_depth]) {
                            // channel for clip
                            cube([contact_width, capsule_radius + wall, disk_depth]);
                        }
                    translate([contact_width / 2, capsule_radius - 0.666, 0]) {
                        cube([contact_width, contact_length, disk_depth]);
                    }
                }
            }
        }
    }
}


// main capsule holder
*translate([capsule_radius * 3.0, 0, 0]) {
    difference() {
        cylinder(r = capsule_radius + wall, h = capsule_height, $fn = facets);
        cylinder(r = capsule_radius + fudge, h = capsule_height, $fn = facets);
    }
}


// contact springs
difference() {
    union() {
        difference() {
            union() {
                cylinder(r = capsule_radius + wall, h = disk_edge, $fn = facets);
                cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
            }
            difference() {
                cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
                cylinder(r = capsule_radius_i, h = disk_depth, $fn = facets);
            }
        }
        // contacts
        contact([contact_border + contact_offset, 0, 0], 0);
        contact([-contact_border - contact_offset, 0, 0], 0);
        // GND contact
        contact([- contact_border - contact_offset, 0, 0], 90);
        // one more radial connection
        rotate([0, 0, -120]) {
            translate([-contact_width / 2, 0, 0]) {
                cube([contact_width, capsule_radius, disk_depth]);
            }
        }
    }
    contact([contact_border + contact_offset, 0, 0], 0, true);
    contact([-contact_border - contact_offset, 0, 0], 0, true);
    contact([- contact_border - contact_offset, 0, 0], 90, true);
    // finally trim the seat for the holder
    translate([0, 0, disk_edge]) {
        difference() {
            cylinder(r = capsule_radius + wall, h = disk_depth, $fn = facets);
            cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
        }
    }
}