//
// Spherical Harmonics Ear Project (*SpHEAR)
//
// TinySpHEAR, First Order (B-format) Ambisonics Microphone
// Common files for H2N add-on array
// 
// Copyright 2016, Fernando Lopez-Lezcano, All Rights Reserved
// nando@ccrma.stanford.edu
//
//  This program is free software: you can redistribute it and/or modify
//  it under the terms of the GNU General Public License as published by
//  the Free Software Foundation, either version 3 of the License, or
//  (at your option) any later version.
//
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//  GNU General Public License for more details.
//
//  You should have received a copy of the GNU General Public License
//  along with this program.  If not, see <http://www.gnu.org/licenses/>.
//
// 3d Models released under the Creative Commons license as follows:
//   Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0)
// http://creativecommons.org/licenses/by-nc-sa/4.0/

include <SpHEAR_common.scad>;
include <TinySpHEAR_common.scad>;
include <TinySpHEAR_mount_pcb.scad>;

// outline of H2N front
// include<h2n/H2N_front_outline.scad>;
// outline of H2N top
// include<h2n/H2N_top_up_outline.scad>;

// dimensions of the EM200 electret microphone capsule (measured 14.59 max)
capsule_radius = 14.6 / 2;
capsule_height = 4.75;
mic_radius = 11;

// dimensions of H2R recorder

// width and depth at middle of ring
h2n_width = 62.00;
h2n_depth = 42.66;

h2n_width_up = 57.0;

module tube(or, ir, h) {
    difference() {
        cylinder(r = or, h = h, $fn = facets);
        cylinder(r = ir, h = h, $fn = facets);
    }
}

// main support ring

module h2n_ring(width, depth, radius, height, slot_w, slot_d, band_wall, wall, col_rad, col_wall) {
    // main support ring
    difference() {
        rounded_block(height, width / 2 + band_wall, depth / 2 +  band_wall, radius - thin_mint);
        rounded_block_relative(height, width / 2 + band_wall, depth / 2 + band_wall, radius - band_wall - thin_mint, - band_wall);
        for (m = [0, 1]) mirror([m, 0, 0]) {
            translate([width / 2 + col_rad - col_wall, 0, 0]) {
                cylinder(r = col_rad, h = height + thin_mint, $fn = facets);
            }
        }
    }
    // inner band
    difference() {
        difference() {
            rounded_block(height, width / 2 + wall - h2n_side_band, depth / 2 + band_wall, radius - thin_mint);
            rounded_block_relative(height, width / 2 + wall - h2n_side_band, depth / 2 + band_wall, radius - wall - thin_mint, - wall);
        }
        for (m = [0, 1]) mirror([m, 0, 0]) {
            // cut slots on the sides
            translate([-width / 2, -h2n_side_band_w / 2, 0]) {
                cube([width / 2, h2n_side_band_w, height]);
            }
        }
    }
}

// side columns

module h2n_columns(width, height, ring_height, tilt, band, transition, radius, wall) {
    // side tubes for cables
    for (m = [0, 1]) mirror([m, 0, 0]) {
        translate([-(width / 2 + mount_radius - wall), 0, 0]) {
            difference() {
                // angled column (4 degrees inward tilt)
                hull() {
                    cylinder(r = radius, h = thin_mint, $fn = facets);
                    translate([height * tan(tilt) - wall/2, 0, height]) {
                        cylinder(r = radius, h = thin_mint, $fn = facets);
                    }
                }
                hull() {
                    cylinder(r = radius - wall, h = thin_mint, $fn = facets);
                    translate([height * tan(tilt) - wall/2, 0, height]) {
                        cylinder(r = radius - wall, h = thin_mint, $fn = facets);
                    }
                }
                // slots in the columns for cables
                translate([mount_radius - wall - ring_height * tan(tilt), - mount_radius * 2, -ring_height]) {
                    slot_height = 25.0;
                    rotate([0, tilt, 0]) {
                        cube([5.0, mount_radius * 4, slot_height]);
                        translate([mount_radius + wall, mount_radius - wall, slot_height]) {
                            rotate([0, 90, 90]) {
                                cylinder(r = mount_radius + wall, h = 15.0, $fn = facets);
                            }
                        }
                    }
                }
            }
        }
        // connector to bridge
        translate([-(width / 2 + mount_radius - wall / 2 - height * tan(tilt)), 0, height]) {
            tube(mount_radius + wall / 2, mount_radius, 5.0);
        }
    }
}

// bridge that connects to capsule array

module semi_cylinder(r, h) {
    difference() {
        cylinder(h, r, r, $fn = facets);
        translate ([-r*2, -r, 0])
            cube([2*r, 2*r, h]);
    }
}

module quarter_sphere(r) {
    difference() {
        sphere(r, $fn = facets);
        translate([-r, -r, -r])
            cube([2*r, 2*r, r]);
        translate([-r, -r, 0])
            cube([r, 2*r, r]);
    }
}

module cylcube(width, depth, height, wall) {
    difference() {
        semi_cylinder(r = depth, h = height);
        semi_cylinder(r = depth - wall, h = height);
    }
    translate([-(width + depth / 2), -depth, 0]) {
        difference() {
            cube([(width + depth / 2), depth * 2, height]);
            translate([0, wall, 0]) {
                cube([(width + depth), (depth - wall) * 2, height]);
            }
        }
    }
}

module h2n_bridge(width, height, ring_height, ring_wall, tilt, band, transition, radius, col_wall, wall) {
    // capsule array mount
    translate([0, 0, band + 20.0]) {
        tetra_capsule_array_mount([-45, 135]);
    }
    // stalk
    translate([0, 0, band]) {
        difference() {
            tube(mount_radius + wall, mount_radius, 20.0 + 1.0);
            // remove stalk segment that is inside the bridge
            translate([width / 2, 0, -1.0]) {
                rotate([0, -90, 0]) {
                    semi_cylinder(r = radius + col_wall, h = width);
                }
            }
        }
    }
    // top of bridge
    translate([width / 2 + wall, 0, band]) {
        rotate([0, -90, 0]) {
            difference() {
                // curvy ceiling
                semi_cylinder(r = radius + col_wall, h = width + 2 * wall);
                semi_cylinder(r = radius + col_wall - wall, h = width + 2 * wall);
                // make a hole for the cables
                translate([0, 0, width / 2]) {
                    rotate([0, 90, 0]) {
                        cylinder(r = mount_radius, h = 10, $fn = facets);
                    }
                }
            }
        }
    }
    // caps at ends
    for (m = [0, 1]) mirror([m, 0, 0]) {
        translate([width / 2 + wall, 0, band]) {
            difference() {
                quarter_sphere(r = radius + col_wall);
                quarter_sphere(r = radius + col_wall - wall);
            }
        }
    }
    // base of bridge
    translate([0, 0, 0]) {
        for (m = [0, 1]) mirror([m, 0, 0]) {
            translate([width / 2 + wall, 0, 0]) {
                cylcube(width / 2 + wall, radius + col_wall, band, wall);
            }
        }
    }
    // reinforcement beams at the base
    translate([-col_wall / 2, -(radius + wall), 0]) {
        cube([col_wall, (radius + wall) * 2, col_wall]);
    }
    for (m = [0, 1]) mirror([m, 0, 0]) {
        translate([-width / 2 + radius, -(radius + wall), 0]) {
            cube([col_wall, (radius + wall) * 2, col_wall]);
        }
    }
}

connector_height = 40;
transition_height = 30;

// measured = 11.50, should be 13.1 -> ratio = 

// h2n_side_radius = 18.2;
h2n_side_radius = 18.4;
h2n_side_band = 1.5;
h2n_side_band_w = 13.1;
h2n_width_m = 63.0;
h2n_depth_m = 36.4;

h2n_band_height = 6.0;

// base band width
h2n_band_wall = 1.6;

// walls for the columns
h2n_col_wall = 2 * wall;

// tilt for the columnds
h2n_col_tilt = 4.0;

// render the whole thing

difference() {
union() {

h2n_ring(h2n_width_m, h2n_depth_m, h2n_depth * 0.425, h2n_band_height, h2n_side_band_w, h2n_side_band, h2n_band_wall, wall, mount_radius, h2n_col_wall);

h2n_columns(h2n_width_m, connector_height, h2n_band_height, h2n_col_tilt, 10.0, transition_height, mount_radius + h2n_col_wall, h2n_col_wall);

*translate([0, 0, connector_height]) {
    h2n_bridge(h2n_width_m - connector_height * tan(h2n_col_tilt), connector_height, 
               h2n_band_height, h2n_band_wall, h2n_col_tilt, 10.0, transition_height, mount_radius, h2n_col_wall, wall);
}

}
*translate([-40, -50, 0]) {
    cube([80, 50, 80]);
}
}

// capsule holders and connector to main body
*rotate([0, 0, 0]) {
    render_tetra_capsule_array(connector_height + transition_height + 30);
}

// make sure dimensions are fine
*translate([-(h2n_width_m - 0.1) / 2, - 0.5, 0]) {
    cube([h2n_width_m - 0.1, 1, 1]);
}
*translate([-0.5, -(h2n_depth_m - 0.1) / 2, 0]) {
    cube([1, h2n_depth_m - 0.1, 1]);
}

// some tests with traced profiles
*difference() {
    translate([0, -2.5, 0]) {
        scale([2.15, 2.15, 1.0]) {
            H2N_top_up_outline(5.0);
        }
    }
// scale([1.75, 1.75, 1.0]) {
    translate([0, -2.4, 0]) {
        scale([2.02, 2.02, 1.0]) {
            H2N_top_up_outline(5.0);
        }
    }
}

*scale(1.665) {
    translate([0, 10, -0]) {
        rotate([0, 0, 0]) {
            H2N_front_outline(1.0);
        }
    }
}
*rotate([0, 0, 4]) translate([35, 0, 0])
    cube([2, 80, 4]);