//
// Test Rig for Primo EM182 capsules
//
// Copyright 2015, Fernando Lopez-Lezcano, All Rights Reserved
// nando@ccrma.stanford.edu
//
//
//  This program is free software: you can redistribute it and/or modify
//  it under the terms of the GNU General Public License as published by
//  the Free Software Foundation, either version 3 of the License, or
//  (at your option) any later version.
//
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//  GNU General Public License for more details.
//
//  You should have received a copy of the GNU General Public License
//  along with this program.  If not, see <http://www.gnu.org/licenses/>.
//
//
// 3d Models released under the Creative Commons license as follows:
//   Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0)
// http://creativecommons.org/licenses/by-nc-sa/4.0/

// dimensions of the EM182 electret microphone
capsule_radius = 5;
capsule_radius_i = 2.2;
capsule_height = 4.5;

// wall thickness of capsule holder
wall = 1;

// contact pads
pad_offset = 3.56;

// slot for contact
// contact_width = 0.85;
contact_width = 1.00;

// length of contact
contact_length = 2.9;

// depth of contact channel (includes contact)
// contact_depth = 0.79;
contact_depth = 0.5;

// island around contact
contact_border = 0.5;

// contact offset from center line
contact_offset = 0.3;

// cutout offset from edge of capsule
contact_cutout = 2.2;
contact_cutout_gnd = 2.5;

// support depth
disk_depth = 0.9;
disk_edge = 0.49;

// thinkness of sleeve
sleeve_edge = 0.66;

// adjustment for the inner radius of the capsule holder
//   measured inside diameter of a trial print was around 7.5 to 8.2 
//   instead of 10, capsule diameter was 9.99)
//   changed from 0.15 to 0.1 for tighter fit
fudge = 0.10;

// number of facets for rendering cylinders
facets = 128;

// one slot for a contact
module contact (trans, angle, cutout, slot = false) {
    rotate([0, 0, angle]) {
        translate(trans) {
            translate([- (contact_width + 2 * contact_border) / 2, 0, 0]) {
                if (slot == false) {
                    difference() {
                        // base for the contact
                        cube([contact_width + 2 * contact_border, capsule_radius + wall / 2, disk_depth]);
                        translate([contact_width / 2, 0, contact_depth]) {
                            // channel for clip
                            cube([contact_width, capsule_radius + wall / 2, disk_depth]);
                        }
                        // cutout for clip from edge of disk
                        translate([contact_width / 2, capsule_radius - cutout, 0]) {
                            cube([contact_width, contact_width, disk_depth]);
                            //cylinder(r = contact_width / 2 * 1.25, h = disk_depth, $fn = facets);
                        }
                    }
                } else {
                    // just the cutouts
                    translate([contact_width / 2, 0, contact_depth]) {
                        // channel for clip
                        cube([contact_width, capsule_radius + wall, disk_depth]);
                    }
                    translate([contact_width / 2, capsule_radius - cutout, 0]) {
                        cube([contact_width, contact_width, disk_depth]);
                        //cylinder(r = contact_width / 2 * 1.25, h = disk_depth, $fn = facets);
                    }
                }
            }
        }
    }
}


// main capsule holder
*translate([capsule_radius * 3.0, capsule_radius * 3, 0]) {
    difference() {
        cylinder(r = capsule_radius + wall, h = capsule_height, $fn = facets);
        cylinder(r = capsule_radius + fudge, h = capsule_height, $fn = facets);
    }
}


// back plate with contact springs
*difference() {
    union() {
        difference() {
            union() {
                cylinder(r = capsule_radius + wall, h = disk_edge, $fn = facets);
                cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
            }
            difference() {
                cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
                cylinder(r = capsule_radius_i, h = disk_depth, $fn = facets);
            }
        }
        // contacts
        contact([contact_border + contact_offset, 0, 0], 0, contact_cutout);
        contact([-contact_border - contact_offset, 0, 0], 0, contact_cutout);
        // GND contact
        contact([- contact_border - contact_offset, 0, 0], 90, contact_cutout_gnd);
        // one more radial connection
        rotate([0, 0, -120]) {
            translate([-contact_width / 2, 0, 0]) {
                cube([contact_width, capsule_radius, disk_depth]);
            }
        }
    }
    // contact cutouts
    contact([contact_border + contact_offset, 0, 0], 0, contact_cutout, true);
    contact([-contact_border - contact_offset, 0, 0], 0, contact_cutout, true);
    // contact cutout for GND
    contact([- contact_border - contact_offset, 0, 0], 90, contact_cutout_gnd, true);
    // finally trim the seat for the holder
    translate([0, 0, disk_edge]) {
        difference() {
            cylinder(r = capsule_radius + wall, h = disk_depth, $fn = facets);
            cylinder(r = capsule_radius, h = disk_depth, $fn = facets);
        }
    }
}

// sleeve that holds everything together
translate([capsule_radius * 3 , 0, 0]) {
    difference() {
        cylinder(r = capsule_radius + 2 * wall, h = capsule_height * 2 / 3, $fn = facets);
        cylinder(r = capsule_radius + wall, h = capsule_height * 2 / 3, $fn = facets);
    }
    difference() {
        cylinder(r = capsule_radius + wall, h = sleeve_edge, $fn = facets);
        cylinder(r = capsule_radius, h = sleeve_edge, $fn = facets);
    }
    // back plate for contacts 1 / 2
    translate([-(contact_width + 2 * contact_border) + 0.1, capsule_radius / 2 - 0.3, 0]) {
        cube([(contact_width + 2 * contact_border) * 2 - 0.2, capsule_radius / 2 + 0.3, sleeve_edge]);
    }
    // back plate for GND contact
    rotate([0, 0, 90]) {
        translate([-(contact_width + 2 * contact_border), capsule_radius * 1 / 3, 0]) {
            cube([(contact_width + 2 * contact_border), capsule_radius * 2 / 3, sleeve_edge]);
        }
    }
}