SpHEAR/TinySpHEAR_mount_pcb.scad

//
// Spherical Harmonics Ear Project (*SpHEAR)
//
// TinySpHEAR, First Order (B-format) Ambisonics Microphone
// Mount for four Zapnspark phantom power printed circuit boards
// 
// Copyright 2015-2016, Fernando Lopez-Lezcano, All Rights Reserved
// nando@ccrma.stanford.edu
//
//  This program is free software: you can redistribute it and/or modify
//  it under the terms of the GNU General Public License as published by
//  the Free Software Foundation, either version 3 of the License, or
//  (at your option) any later version.
//
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//  GNU General Public License for more details.
//
//  You should have received a copy of the GNU General Public License
//  along with this program.  If not, see <http://www.gnu.org/licenses/>.
//
// 3d Models released under the Creative Commons license as follows:
//   Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0)
// http://creativecommons.org/licenses/by-nc-sa/4.0/

include <TinySpHEAR_common.scad>;
include <CCRMA_logo.scad>;

////
//// default model parameters
////

// size of Zapnspark printed circuit board
// (ideal size in Kicad design)
pcb_length = 79.375;
pcb_width = 19.050;
// (specification of ultimaker pcb material)
pcb_thickness = 1.61;

// tolerance to add to length and width of pcb
//
// printed with pcb_fit = 0.25 -> 19.05 + 0.25 = 19.3 (ideal printed)
//   measured printed = 19.04 - 0.25 = 18.79 (ultimaker 2 plus, 2016.08.23)
//   measured pcb width = 18.85 (diff = 0.06, othermill)
//
pcb_fit = 0.2;

// tolerance add to thickness of pcb
//
// printed with pcb_tfit = 0.3 -> 1.61 + 0.3 = 1.91 (ideal printed)
// measured print channel = 1.85 : 0.06 thinner (ultimaker 2 plus, 2016.08.23)
// measured pcb thickness = 1.58 (othermill)
//
pcb_tfit = 0.15;

// we leave part of the pcb exposed on the bottom of the body so that we
// can solder the wires that connect the microphone with the
// preamplifier, same at the top of the pcb to solder the wires
// to the capsules
pcb_low_exp = 12.0;
pcb_hi_exp = 8.0;

// clearance from the bottom and top of pcb's to the start of the flare,
// this adds space for the protuding molex pins on which we solder
pcb_low_clear = 15.0;
pcb_hi_clear = 15.0;

// diameter of four conductor cable
cable_diam = 9.5;

// lip that mounts flares into main body box
mount_lip = 6.0;

// main body corner radius
mount_corner = 15.0;

// capsule array mount, height of flare and stalk
flare_height = 50;
stalk_height = 40;

// lip fit for flares
// 0.20 seems to be fine (0.3 was too lose)
lip_fit = 0.20 / 2;

// wall thickness
wall = 1.0;

// back and front clearance of pcb (components and leads)
pcb_front = 13.25;
pcb_back = 3.0;

// calculated minimum "radius" of microphone box
box_radius = pcb_front + (pcb_thickness + pcb_tfit) + pcb_back + 2 * wall;

// shock mount parameters
//

ring_sep = 30.0;
ring_height = 10.0;
rubber_band_angle = 40;
main_radius_inc = (ring_sep / 2) / tan(rubber_band_angle);

// gap between internal ring and microphone body
internal_ring_gap = 1.0;

// connector that joins the two internal rings
connector_w = 10.0;
connector_d = 2.0;

// the printed circuit board

module pcb(length, width, thick) {
    translate([-width/2, 0, 0]) {
        cube([width, thick, length]);
    }
}

// the printed circuit board plus space in the front and back for components

module pcb_clear(length, width, thick, slot_depth, front, back) {
    translate([0, - (thick + front)]) {
        pcb(length, width, thick);
        // clear space in the front
        translate([- (width/2 - slot_depth), thick, 0]) {
            cube([width - 2 * slot_depth, front, length]);
        }
        // clear space in the back
        translate([- (width/2 - slot_depth), - back, 0]) {
            cube([width - 2 * slot_depth, back, length]);
        }    
    }
}

// all four printed circuit boards

module tetra_pcb_clear(length, width, thick, slot_depth, front, back) {
    for (rot = [0, 90, 180, 270]) {
        rotate([0, 0, rot]) {
            pcb_clear(pcb_length + pcb_fit, pcb_width + pcb_fit, pcb_thickness + pcb_tfit, slot_depth, front, back);
        }
    }
}

// box with rounded corners

module tetra_mount_box(height, radius, corner) {
    rd = radius - corner;
    minkowski() {
        translate([-rd, -rd, 0]) {
            cube([rd * 2, rd * 2, height / 2]);
        }
        cylinder(r = corner, h = height / 2, $fn = facets);
    }
}

// inset box with rounded corners

module tetra_mount_box_relative(height, ref_radius, ref_corner, radius_inc) {
    corner = ref_corner * ((ref_radius + radius_inc) / ref_radius);
    tetra_mount_box(height, ref_radius + radius_inc, corner);
}

// the main body of the microphone mount

module tetra_mount_body(height, radius, corner, lower_lip, upper_lip, clear) {
    difference() {
        tetra_mount_box(height, radius, corner);
        union() {
            // hollow out the inside with slots for pcbs
            tetra_pcb_clear(pcb_length, pcb_width, pcb_thickness, 1.0, pcb_front, pcb_back);
            // trim square angles
            cylinder(r = pcb_front, h = height, $fn = facets);
            // remove slots from inside body
            slot_len = 30;
            translate([0, 0, slot_len]) {
                    tetra_mount_box_relative(height, radius, corner, - (2 * wall));
            }
            // upper lip for flare to microphone
            translate([0, 0, height - upper_lip]) {
                difference() {
                    tetra_mount_box(upper_lip, radius, corner);
                    tetra_mount_box_relative(upper_lip, radius, corner, -(wall + lip_fit));
                }
            }
            // lower lip for flare to cable
            translate([0, 0, 0]) {
                difference() {
                    tetra_mount_box(lower_lip, radius, corner);
                    tetra_mount_box_relative(lower_lip, radius, corner, -(wall + lip_fit));
                }
            }
        }
    }
    // add parts for clearance check
    if (clear == 1) {
        // electrolytic capacitors
        cap_diam = 10.2;
        for (rot = [0, 180, 270]) {
            rotate([0, 0, rot]) {
                translate([-pcb_front + cap_diam/2, 0, 0]) {
                    *cylinder(r = (cap_diam/2), h = 20, $fn = facets);
                }
            }
        }
        // PCBs
        for (rot = [0, 180, 270]) {
            rotate([0, 0, rot]) {
                translate([-(pcb_front + pcb_thickness), -pcb_width/2, -pcb_low_exp]) {
                    cube([pcb_thickness, pcb_width, pcb_length]);
                }
            }
        }
        // connectors
        cap_h = 12.3;
        cap_w = 10.53/2;
        for (rot = [0, 180, 270]) {
            rotate([0, 0, rot]) {
                translate([-pcb_front, -cap_w/2 - 2.5, 0]) {
                    *cube([cap_h, cap_w, 20]);
                }
            }
        }
    }
}

// flares from the body to the microphone stalk and cable

module tetra_mount_flare(height, lip, transition, bot_radius, bot_corner, top_radius, stalk_height, dot) {
    // bottom rounded box
    difference() {
        tetra_mount_box(height, bot_radius, bot_corner);
        tetra_mount_box_relative(height, bot_radius, bot_corner, -(2 * wall));
        // flange to mount on body
        // temporarily add 0.05 for best fit on already printed body (FIXME)
        tetra_mount_box_relative(lip + 1.0, bot_radius, bot_corner, - (wall + 0.05));
    }
    // flare to round section
    translate([0, 0, height]) {
        difference() {
            hull() {
                tetra_mount_box(1, bot_radius, bot_corner);
                translate([0, 0, transition]) {
                    cylinder(r = top_radius, h = 1, $fn = facets);
                }
            }
            hull() {
                tetra_mount_box_relative(1, bot_radius, bot_corner, - 2 * wall);
                translate([0, 0, transition]) {
                    cylinder(r = top_radius - wall, h = 1, $fn = facets);
                }
            }
        }
    }
    // cylindrical stalk
    translate([0, 0, height + transition]) {
        difference() {
            cylinder(r = top_radius, h = stalk_height, $fn = facets);
            cylinder(r = top_radius - wall, h = stalk_height, $fn = facets);
        }
        // add marker for "back of microphone" orientation
        if (dot == 1) {
            rotate([0, 0, 90]) {
                translate([0, top_radius - wall * 2 / 3, stalk_height - top_radius]) {
                    difference() {
                        sphere(r = top_radius / 3, $fn = 32);
                        translate([0, -top_radius + top_radius / 2, 0]) {
                            cube([top_radius, top_radius, top_radius], center = true);
                        }
                    }
                }
            }
        }
    }
}

// top conical section that plugs into capsule array

module tetra_capsule_array_mount(angles) {
    difference() {
        translate([0, 0, 0]) {
            rotate([0, 0, 45]) {
                difference() {
                    ellipsoid(mount_top_height, mount_radius + wall, mount_radius_capsule, mount_top_eccentricity);
                    ellipsoid(mount_top_height, mount_radius, mount_radius_capsule * 0.5, mount_top_eccentricity * 1.05);
                }
            }
        }
        // indentations that match the two lower capsule holders
        // add ridge height adjustment
        translate([0, 0, mount_top_height + (mic_radius - capsule_height) + capsule_height * cos(elev_angle)]) {
            rotate([0, (90 + elev_angle), angles[0]]) {
                translate([0, 0, mic_radius - capsule_height]) {
                    capsule([], 0, 1, 0.1, 3, 1);
                }
            }
            rotate([0, (90 + elev_angle), angles[1]]) {
                translate([0, 0, mic_radius - capsule_height]) {
                    capsule([], 0, 1, 0.1, 3, 1);
                }
            }
        }
    }
}

// internal ring of shock mount

module tetra_shock_mount_internal_ring(height, radius, corner, gap, lip) {
    slot_sep = radius * 2 / 2.5;
    slot_w = 5;
    slot_o = height / 3;
    difference() {
        union() {
            // base ring
            difference() {
                tetra_mount_box_relative(slot_o, radius + gap, corner, 3 * wall);
                tetra_mount_box(slot_o, radius + gap, corner);
            }
            // upper ring with slots for rubber bands
            difference() {
                tetra_mount_box_relative(height, radius + gap + 2 * wall, corner, 2 * wall);
                tetra_mount_box_relative(height, radius + gap + wall, corner, 1 * wall);
                for (rot = [0, 90, 180, 270]) rotate([0, 0, rot]) {
                    // slots for rubber bands
                    minkr = 1.25;
                    for (m = [0, 1]) mirror([0, m, 0]) {
                        translate([-slot_w / 2 + slot_sep, radius + gap, slot_o + minkr]) {
                            minkowski() {
                                cube([slot_w - minkr, 10, slot_o - minkr]);
                                rotate([90, 0, 0]) cylinder(r = minkr, h = 1, $fn = facets);
                            }
                            translate([slot_w / 2, -2, 0]) {
                                cube([slot_w / 2, 10, 10]);
                            }
                        }
                    }
                }
            }
            // body for bars that connect both rings together
            for (rot = [0, 90, 180, 270]) rotate([0, 0, rot]) {
                translate([radius + gap + 3 * wall, -(connector_w/2 + wall), 0]) {
                    cube([connector_d + wall, connector_w + 2 * wall, height]);
                }
                for (m = [0, 1]) mirror([0, m, 0]) {
                    translate([radius + gap + 4 * wall, -(connector_w/2 + wall), 0]) {
                        cylinder(r = wall * 2, h = height, $fn = 3);
                    }
                }
            }
        }
        // carve holes for bars that connect both rings
        for (rot = [0, 90, 180, 270]) rotate([0, 0, rot]) {
            translate([radius + gap + 3 * wall, -connector_w/2, 0]) {
                cube([connector_d, connector_w, height - 2.75 * wall]);
                translate([connector_d / 2, 0, height - 3 * wall]) {
                    rotate([-90, 0, 0]) {
                        cylinder(r = connector_d / 2, h = connector_w, $fn = facets);
                    }
                }
            }
        }
    }
    for (rot = [0, 90, 180, 270]) rotate([0, 0, rot]) {
        // lip to support microphone on lower ring only
        if (lip == 1) {
            lip_w = 10;
            translate([radius + gap + 2.5 * wall, -lip_w/2, height]) {
                rotate([90, 90, 180]) {
                    linear_extrude(height = lip_w) {
                        polygon([[0, 0], [0, 4], [1, 4], [height * 2/3, 0]]);
                    }
                }
            }
        }
    }    
}

// eyelet for connecting the external ring to the stand mount

module tetra_shock_mount_ring(outside_radius, inside_radius, thickness) {
    difference() {
        union() {
            cylinder(r = outside_radius, h = thickness, $fn = facets);
            translate([0, -outside_radius, 0]) {
                cube([outside_radius, outside_radius, thickness]);
            }
        }
        cylinder(r = inside_radius, h = thickness, $fn = facets);
    }
}

// external ring of shock mount (connects to stand mount)

module tetra_shock_mount_external_ring(height, radius, corner, gap, lip) {
    difference() {
        tetra_mount_box_relative(6, radius, mount_corner, gap);
        tetra_mount_box_relative(6, radius, mount_corner, gap - 4 * wall);
    }
    for (rot = [0, 90, 180, 270]) {
        rotate([0, 0, rot]) {
            translate([radius + gap + 4 * wall, -7.5, 0]) {
                cube([4, 15, 6]);
            }
            translate([radius + gap, -2, 0]) {
                cube([7, 4, 6]);
            }
        }
    }
    // connection to stand mount
    translate([0, 18, 0]) {
        intersection() {
            difference() {
                tetra_mount_box_relative(6, radius, mount_corner - 5, gap);
                tetra_mount_box_relative(6, radius, mount_corner - 5, gap - 4 * wall);
            }
            translate([-(radius + 2 * mount_corner), 0, 0]) {
                cube([2 * (radius + 2 * mount_corner), radius + 2 * mount_corner, 6]);
            }
        }
    }
    // connection to hub
    translate([-2, radius + 2 * mount_corner + 12, 0]) {
        cube([4, 10, 6]);
    }
    // rotating mount
    o_rad = 8;
    i_rad = 3;
    thk = 4;
    rotate([0, 90, 0]) {
        translate([-o_rad, 66, -2]) {
            tetra_shock_mount_ring(o_rad, i_rad, thk);
        }
    } 
}

// connector that joins the two internal rings

module tetra_shock_mount_connector(length, lip, width, thickness, fit) {
    cube([length + 2 * lip , width - 2 * fit, thickness - 2 * fit]);
    translate([lip, -(thickness / 2), 0])
        cube([length , width + thickness, thickness * 3 / 2]);
}

// mount to standard microphone clip stand mount

module tetra_shock_mount_stand(height, wall, stand_wall) {
    // stand mount
    translate([0, 0, 0]) {
        difference() {
            union() {
                // main mount cylinder
                translate([0, 0, 0]) {
                    difference() {
                        cylinder(r = mic_mount_radius + mic_mount_fit + stand_wall, 
                                h = height, $fn = facets);
                        // make the hole for the mount (* 1.5 to cut the ridge as well)
                        cylinder(r = mic_mount_radius + mic_mount_fit, h = height, $fn = facets);
                    }
                }
            }
            // slot for fitting into microphone stand
            translate([mic_mount_radius - stand_wall / 2, - mic_mount_slot_width / 2, 0]) {
                cube([2 * stand_wall, mic_mount_slot_width, mic_mount_slot_height]);
            }
            // eyelet for microphone stand
            translate([mic_mount_radius - stand_wall / 2, 0,  mic_mount_slot_height]) {
                rotate([0, 90, 0]) {
                    cylinder(r = mic_mount_slot_radius, h = 2 * stand_wall, $fn = facets);
                }
            }
        }
        // top of mount
        translate([0, 0, height]) {
            difference() {
                cylinder(h = mic_mount_radius, 
                        r1 = mic_mount_radius + mount_wall + wall + mic_mount_fit, r2 = 5, $fn = facets);
                cylinder(h = mic_mount_radius, 
                        r1 = mic_mount_radius + mount_wall + mic_mount_fit, r2 = 1, $fn = facets);
            }
            translate([0, 0, mic_mount_radius - 1]) {
                cylinder(h = 1, r = 5, $fn = facets);
            }
        }
        // eyelets
        o_rad = 8;
        i_rad = 3;
        thk = 4;
        for (m = [0, 1]) mirror([0, m, 0]) {
            rotate([90, 90, 0]) {
                translate([-(height + o_rad + 6), 0, thk/2 + fit]) {
                    rotate([0, 0, 45]) 
                        tetra_shock_mount_ring(o_rad, i_rad, thk);
                }
            }
        }
    }
}

////
//// render all the different parts
////

// microphone body: flare to capsule array (slips into PCB holder body)
//

module render_tetra_capsule_flare(z_offset) {
    translate([0, 0, z_offset]) {
        tetra_mount_flare(pcb_hi_clear + pcb_hi_exp, 
                    mount_lip, flare_height, box_radius + wall,  mount_corner, mount_radius + wall, stalk_height, 1);
        translate([0, 0, pcb_hi_clear + pcb_hi_exp + flare_height + stalk_height]) {
            tetra_capsule_array_mount([-45, 135]);
        }
    }
}

// microphone body: main body, holds printed circuit boards
//
tetra_pcb_mount_height = pcb_length - pcb_low_exp - pcb_hi_exp;

module render_tetra_pcb_mount(z_offset, showint) {
    translate([0, 0, z_offset]) {
        tetra_mount_body(tetra_pcb_mount_height, box_radius + wall, mount_corner, mount_lip, mount_lip, showint);
    }
    // add ccrma logo
    rotate([0, 0, -90]) {
        translate([0, -(box_radius - 0.5), tetra_pcb_mount_height / 2]) {
            rotate([90, 270, 0]) {
                logo_scale = 1/2;
                scale([logo_scale, logo_scale, 1.0]) {
                    ccrma_logo(1.75);
                }
            }
        }
    }
}

// microphone body: flare to microphone cable (slips into PCB holder body)
//

module render_tetra_cable_flare(z_offset, flip) {
    translate([0, 0, z_offset]) {
        tetra_mount_flare(pcb_low_clear + pcb_low_exp, mount_lip, 20, box_radius + wall, mount_corner, cable_diam / 2 + wall, 10, 0);
    }
}

// microphone body: render all parts with a vertical separation
//

module render_tetra_body(z_offset, spread, showint) {
    rotate([0, 180, 0]) {
        render_tetra_cable_flare(0);
    }
    lippy = spread - mount_lip;
    render_tetra_pcb_mount(lippy, showint);
    render_tetra_capsule_flare(tetra_pcb_mount_height + 2 * lippy);
}

// microphone: render the full assembly with a vertical separation
//

module render_tetra_microphone(z_offset, spread) {
    render_tetra_body(z_offset, spread);
    lippy = spread - mount_lip;
    render_tetra_capsule_array(z_offset + tetra_pcb_mount_height + mount_top_height +
            flare_height + stalk_height + pcb_hi_clear + pcb_hi_exp + 2 * lippy + spread + mic_radius);
}

// microphone: render the full assembly with a vertical separation
//             cut out halt of the assembly so that we can see the inside
//

module render_tetra_microphone_cutout(z_offset, spread) {
    difference() {
        render_tetra_microphone(z_offset, spread);
        // a cube that blots out half the microphone
        translate([0, -50, -50]) {
            cube([50, 100, 650]);
        }
    }
}

// shock mount: microphone clip on stand mount
//

module render_tetra_shock_mount_stand(z_offset) {
    translate([z_offset]) {
        tetra_shock_mount_stand(mic_mount_height, mount_wall, mic_mount_wall);
    }
}

// shock mount: external ring
//

module render_tetra_shock_mount_external_ring(z_offset) {
    translate([0, 0, z_offset]) {
        tetra_shock_mount_external_ring(ring_height, box_radius + wall, mount_corner, main_radius_inc, 0);
    }
}

// shock mount: bottom internal ring
//

module render_tetra_shock_mount_internal_ring_bot(z_offset) {
    translate([0, 0, z_offset]) {
        tetra_shock_mount_internal_ring(ring_height, box_radius + wall, mount_corner, internal_ring_gap, 1);
    }
}

// shock mount: all four internal ring connectors
//

module render_tetra_shock_mount_ring_connectors(offset) {
    for (o = [0, 1, 2, 3]) {
        translate([-18, (10 + offset) * o, 0]) {
            tetra_shock_mount_connector(ring_sep, 4, connector_w, connector_d, 0.1);
        }
    }
}

// shock mount: top internal ring
//

module render_tetra_shock_mount_internal_ring_top(z_offset) {
    translate([0, 0, z_offset]) {
        tetra_shock_mount_internal_ring(ring_height, box_radius + wall, mount_corner, internal_ring_gap, 0);
    }
}

// shock mount: render all parts
//

module render_tetra_shock_mount(z_offset) {
    // internal rings
    translate([0, 0, z_offset + ring_sep / 2]) {
        render_tetra_shock_mount_internal_ring_top(0);
        rotate([0, 180, 0]) {
            render_tetra_shock_mount_internal_ring_bot(ring_sep + 2);
        }
        // insert the connecting rods
        for (r = [0, 90, 180, 270]) {
            rotate([0, 0, r]) {
                translate([box_radius + 3 * wall + internal_ring_gap, 0, -1]) {
                    rotate([0, 90, 0]) {
                        translate([-4, -5, 1]) {
                            tetra_shock_mount_connector(ring_sep, 4, connector_w, connector_d, 0.1);
                        }
                    }
                }
            }
        }
    }
    // external ring
    translate([0, 0, z_offset - ring_height / 4]) {
        render_tetra_shock_mount_external_ring(0);
    }
    // mount to stand
    translate([0, 85, -(mic_mount_height + mic_mount_radius + ring_height / 4)]) {
        rotate([0, 0, 90]) {
            render_tetra_shock_mount_stand(0);
        }
    }
}